Библиотеки для симуляторов

[lart]

Модель для 2SJ162 (комплементарна 2SK1058)

.MODEL 2SJ162 PMOS (VTO=842.193M KP=20U L=2U W=21.3317M GAMMA=0 PHI=600M LAMBDA=20.7067M RD=837.199M CBD=2.96862N IS=10F CGSO=1.13517N CGDO=1.13517N TOX=0 NSUB=0 TPG=1 UO=600 RG=50 RDS=1MEG )

[Elick]

Перенёс просьбу в другую тему, как это сообщение удалить не нашёл... 

[access777]

http://valvolodin.narod.ru/articles/Ir/An/an-975.pdf
http://my.ece.ucsb.edu/bobsclass/194/References/SPICE_3rd_party_models.pdf

[Elick]

Есть следующие вопросы к знатокам симуляции.

На сайтах некоторых производителей лежат модели в разных вариантах, наверно под разные софтины. Встречаются названия Spice2, Spice3, PSpice, Saber. Соответственно и файлы с разными расширениями: .lib, .sin, .sp2, .sp3, и так далее.

Вопрос 1. Какие из перечисленных файлов подходят для LTspice непосредственно?
Вопрос 2. Можно ли подточить напильником неродной файл, чтобы подошел для LTspice? Если да, то что конкретно нужно сделать для того?
Вопрос 3. Что нужно прочитать НА РУССКОМ, чтобы перестать уже задавать дурацкие вопросы?

 

1. Lib подходит. Из названий я подключаю текстовые файлы Spice2.
2. Точить можно, но я этим не занимался, т.к. камрад Lart доходчиво объяснил что и как искать, и чуть выше как вставлять.
3. Камрад TrueVAL поделился со мной литературой по этой теме. Не думаю, что там есть секретные материалы, поэтому тут. http://www.onlinedisk.ru/file/965761/

[Elick]

Набрёл, мож кому пригодится...
http://www.madlabo.com/mad/edat/spice/model/index.htm

[Elick]

http://espice.ugr.es/espice/src/modelos_subckt/ZMODELS.LIB

От ZETEX-a

[Moonlight]

Понадобился мне драйвер ucc37322, погуглив обнаружил форум http://www.offtop.ru/gauss2k/v7_696421_1.php?of991=g61thl06k9s655qpv4fqidkpp4 но так и не разобрался как это засунуть в свкад. Нарисовал корпус с ножками, сделал файл .lib но в итоге ничего не происходит. Может кто умеет это делать и поможет мне запустить модельку?

[Peratron]

@ Moonlight

Плз, перенеси обсуждение в другую тему - пусть эта останется только для размещения библиотек или ссылок на источники оных...

[Elick]

Господа, есть у кого моделька для 2SJ308. Очень надо. Поиском не решил, поможите, плиз...

[edit]Не знаю, было или нет, модели от IR
http://www.irf.com/product-info/models/model_links.html[/edit]

[Elick]

Ещё небольшая подборка моделек, мож кому сгодится:
http://tw.myblog.yahoo.com/interesting-science/article?mid=1431
http://tw.myblog.yahoo.com/interesting-science/article?mid=1432&prev=1436&l=a&fid=25

[Peratron]

Ну, очень хочется 4053, но до кучи приму с благодарностью и прочие аналоговые КМОП-ключи из 4000 серии.

[Peratron]

http://www.chemroc.com/PSPICE.html

Калькулятор, создающий спайс-модель лампового триода по картинке ВАХ.

[Peratron]

Ищется адекватная модель 2N7000.

Обычно этот транзистор имеется в штатных библиотеках - по крайней мере в ОрКАДе и в ПРОТЕУСе оно есть.

Но что-то ВАХи реальных камней не сходятся с модельными.
При том, что данные из мануалов, причём, от разных производителей, гораздо ближе к реальности (плюс/минус немалый производственный разброс, конечно).

ХИНТ: в первую очередь интересны характеристики при малых токах - в единицы мА.
То есть, на пороге открывания.

Кто нибудь правильной моделькой располагает?

Конечно, если припрёт - придётся садиться и лепить самому.
Но, блин, лениво ж!
Ну, неужто на это сверхизвестное ... нет правильной модели?!
 :o

[lart]

Если я правильно понимаю, 2N7002 - это тот же 2N7000, но в SMD упаковке.
В штатной библиотеке LTSpice имеется вот такая модель:

.model 2N7002 VDMOS(Rg=3 Vto=1.6 Rd=0 Rs=.75 Rb=.14 Kp=.17 mtriode=1.25 Cgdmax=80p Cgdmin=12p Cgs=50p Cjo=50p Is=.04p mfg=Fairchild Vds=60 Ron=2 Qg=1.5n)

[Peratron]

Псб.
Попробую.
Но 7002 есть в библиотеках, как и 7000 - тоже с какими то левыми характеристиками...

[Vitalka]

http://www.chemroc.com/PSPICE.html

Калькулятор, создающий спайс-модель лампового триода по картинке ВАХ.

Какие требования по разрешению к картинке? А то с триодной части 6ф1п модель сделать не получается что-то вообще

[Peratron]

* TL431
*****************************************************************************
* (C) Copyright 2009 Texas Instruments Incorporated. All rights reserved.                                           
*****************************************************************************
** This model is designed as an aid for customers of Texas Instruments.                                             
** TI and its licensors and suppliers make no warranties, either expressed                                          
** or implied, with respect to this model, including the warranties of                                                   
** merchantability or fitness for a particular purpose. The model is                                                      
** provided solely on an "as is" basis. The entire risk as to its quality                                                   
** and performance is with the customer                                                                                             
*****************************************************************************
*
* This model was developed for Texas Instruments Incorporated by:
*   AEi Systems, LLC
*   5777 W. Century Blvd., Suite 876
*   Los Angeles, California  90045
*
* This model is subject to change without notice. Neither Texas Instruments Incorporated
* nor AEi Systems is responsible for updating this model.
* For more information regarding modeling services, model libraries and simulation
* products, please call AEi Systems at (310) 216-1144, or contact AEi Systems by email:
* info@AENG.com. Or visit AEi Systems on the web at http://www.AENG.com.
*
*****************************************************************************
*
** Released by: Analog eLab Design Center, Texas Instruments Inc.
* Part: TL431
* Date: 12/14/2009
* Model Type: Transient and AC 
* Simulator: PSPICE 
* Simulator Version: 16.0.0.p001
* Datasheet: SLVS543J - AUGUST 2004 - REVISED DECEMBER 2005
*
*****************************************************************************
*
* Updates:
*
* Final 2.00
* Changed encrypted model to unencrypted.
*
* Final 1.00
* Release to Web.
*
*****************************************************************************
.SUBCKT TL431+ 7 6 11
*             K A FDBK
V1 1 6 2.495
R1 6 2 15.6
C1 2 6 .5U
R2 2 3 100
C2 3 4 .08U
R3 4 6 10
GB1 6 8 VALUE = {IF(V(3,6)< 0 , 1.73*V(3,6) -1U , -1U)}
D1 5 8 DCLAMP
D2 7 8 DCLAMP
V4 5 6 2
G1 6 2 1 11 0.11
.MODEL DCLAMP D (IS=13.5N RS=25M N=1.59
+ CJO=45P VJ=.75 M=.302 TT=50.4N BV=34V IBV=1MA)
.ENDS

[Добрый Кот]

Добрый день.
Есть у кого нибудь спайс модель 6С19П, поделитесь пожалуйста.

[Jinx]

@ Добрый Кот

Можете взять мою общую модель и адаптировать по ВАХ из паспорта. ECC83 для примера есть.

Код: [Выделить]

*******************************************************************************
* Generic thermionic triode valve model with improved grid current, low mu at *
* high Va, and kinked positive grid voltage curves.                           *
* Copyright (c) Orson J. Maxwell 2018                                         *
*******************************************************************************
.SUBCKT THERMTRIODE A G C
+ PARAMS: MU=100 EX=1.4 KG1=900 KP=600 KVB=300; Koren params w/o RGI
+ GO=0.6 ; Grid offset - helps model increased Ia on low Va
+ CCG=3.8P CGA=0.05P CCA=5.3P ; Interelectrode capacitances
+ GCO=-0.9 GCP=2.5 GCM=5.4e-5 ; Grid current offset, proportion, and magnitude
* Anode current
Eanode  7 0 VALUE=
+{V(A,C)/KP*LOG(1+EXP(KP*(1/MU+(V(G,C)+{GO})/SQRT(KVB+V(A,C)*V(A,C)))))}
REanode 7 0 1G
Ganode  A C VALUE={PWR(V(7),EX)/KG1}
Rac     A C 1G    ; Tie floating nodes
* Interelectrode capacitances
Cgc     G C {CCG} ; Cathode-grid capacitance
Cga     G A {CGA} ; Grid-anode capacitance
Cca     A C {CCA} ; Cathode-anode capacitance
* Grid current
Ggrid   G C VALUE=
+{PWR(LIMIT{V(G,C)-{GCO},0,1E6},{GCP})*({GCM}+((300-V(A,C))/2e6))}
.ENDS
*******************************************************************************

.SUBCKT ECC83JCA A G C
XV1 A G C THERMTRIODE
+ PARAMS: MU=100 EX=1.4 KG1=900 KP=600 KVB=300 GO=0.6
+ CCG=1.6P CGA=1.7P CCA=.33P
+ GCO=-0.9 GCP=2.5 GCM=5.4e-5
.ENDS ECC83JCA
Раз пошла такая пьянка, то приеду домой и общую модель пентода, включенного как тетрод тоже положу. Модель менее перегружена (быстрее симулируется), чем та, что от Дункана Манро, но и не валит SPICE движок на перегрузе во временном домене, как например модель Нормана Корена.

[Jinx]

Код: [Выделить]

*******************************************************************************
* Generic thermionic pentode valve model with improved grid current, screen   *
* grid complimentary current and realistic curve clamping.                    *
* Copyright (c) Orson J. Maxwell 2018                                         *
*******************************************************************************
.SUBCKT THERMPENTODE A G C S
+ PARAMS: MU=56 EX=1.35 KG1=630 KG2=4800 KP=110 KVB=9; Koren params /o RGI
+ TCC=1e-4 ; Transconductance curve tilt
+ CCG=4P CGA=5.5P CCA=.33P ; Interelectrode capacitances
+ GCO=-0.9 GCP=2.5 GCM=5.4e-5 ; Grid current offset, proportion, and magnitude
* Anode current
RE1 7 0 1G
E1 7 0 VALUE=
+{V(S,C)/KP*LOG(1+EXP((1/MU+V(G,C)/V(S,C))*KP))+V(A,C)*{TCC}}
Ganode  A C VALUE={PWR(V(7),EX)/KG1*ATAN(V(A,C)/KVB)}
*Gscreen S C VALUE={PWR((V(S,C)/MU+V(G,C)),EX)/KG2}
Etotal  8 0 VALUE={PWR(V(7),EX)/KG2}
Gscreen S C VALUE={V(8)-I(GANODE)}
Rac     A C 1G    ; Tie floating nodes
* Interelectrode capacitances
Cgc     G C {CCG} ; Cathode-grid capacitance
Cga     G A {CGA} ; Grid-anode capacitance
Cca     A C {CCA} ; Cathode-anode capacitance
* Grid current
Ggrid   G C VALUE=
+{PWR(LIMIT{V(G,C)-{GCO},0,1E6},{GCP})*({GCM}+((300-V(A,C))/2e6))}
.ENDS
*******************************************************************************

.SUBCKT EF86JCA A G C S
XV1 A G C S THERMPENTODE
+ PARAMS: MU=56 EX=1.35 KG1=630 KG2=340 KP=110 KVB=9 TCC=1e-4
+ CCG=1.6P CGA=1.7P CCA=.33P
+ GCO=-0.9 GCP=2.5 GCM=5.4e-5
.ENDS EF86JCA